Oracle自治事务实例讲解

一、自治事务使用情况

无法回滚的审计 ： 一般情况下利用触发器禁止某些对表的更新等操作时，若记录日志，则触发器最后抛出异常时会造成日志回滚。利用自治事务可防止此点。 

避免变异表： 即在触发器中操作触发此触发器的表 

在触发器中使用ddl 写数据库：对数据库有写操作（insert、update、delete、create、alter、commit）的存储过程或函数是无法简单的用sql来调用的，此时可以将其设为自治事务，从而避免ora-14552（无法在一个查询或dml中执行ddl、commit、rollback）、ora-14551（无法在一个查询中执行dml操作）等错误。需要注意的是函数必须有返回值，但仅有in参数（不能有out或in/out参数）。 

开发更模块化的代码： 在大型开发中，自治事务可以将代码更加模块化，失败或成功时不会影响调用者的其它操作，代价是调用者失去了对此模块的控制，并且模块内部无法引用调用者未提交的数据。 

二、Oracle 自制事务 

Oracle 自制事务是指的存储过程和函数可以自己处理内部事务不受外部事务的影响，用pragma autonomous_transaction来声明，要创建一个自治事务，您必须在匿名块的最高层或者存储过程、函数、数据包或触发的定义部分中，使用PL/SQL中的PRAGMA AUTONOMOUS_TRANSACTION语句。在这样的模块或过程中执行的SQL语句都是自治的。 

结束一个自治事务必须提交一个commit、rollback或执行ddl，否则会产生Oracle错误ORA-06519: active autonomous transaction detected and rolled back 。 

三、实例 

------------------------------------------------------------------------- 
-- 存储过程名：P_DTMS_UPDATE_SAP 
-- 插入数据到T_DATA_DTMS_TAX_EXPORTTOSAP中 
-- 自治事务（pragma autonomous_transaction） 
-- 2012-12-28 
------------------------------------------------------------------------- 
create or replace procedure P_DTMS_UPDATE_SAP( 
i_pkvalue in number, 
i_opcontent_ori in VARCHAR2, 
i_opcontent_dest in VARCHAR2, 
i_source in varchar2 
) 
is 
pragma autonomous_transaction; 
begin 
INSERT INTO T_DATA_DTMS_TAX_EXPORTTOSAP(ID, DTMS_TAX_INVOICE_ID, OPERATE_TYPE, EXPORT_TO_SAP_ORI, EXPORT_TO_SAP_DEST, OPERATE_TIME, SOURCE) 
    VALUES(SEQ_DATA_DTMS_TAX_EXPORTTOSAP.NEXTVAL,i_pkvalue,'update',i_opcontent_ori,i_opcontent_dest,sysdate, i_source); 
commit; 
end; 
------------------------------------------------------------------------- 
-- 触发器名称：TRG_INVOICE_EXPORTTOSAP_MODIFY 
-- 当表T_DTMS_TAX_INVOICE做更新操作时触发，用于对EXPORT_TO_SAP标志位做将1改为0时，抛出异常，回滚修改，即：不允许将EXPORT_TO_SAP从1改为0 
-- 2012-12-28 
------------------------------------------------------------------------- 
create or replace trigger "TRG_INVOICE_EXPORTTOSAP_MODIFY" 
  after update 
  on T_DTMS_TAX_INVOICE 
  for each row 
declare v_pkvalue NUMBER(20); 
        v_opcontent_ori VARCHAR2(50);--修改前的值 
        v_opcontent_dst VARCHAR2(50);--修改后的值 
begin 
  v_pkvalue := :new.id; 
  case when updating then 
    v_opcontent_ori := :old.EXPORT_TO_SAP; 
    v_opcontent_dst := :new.EXPORT_TO_SAP; 
    if v_opcontent_ori = 1 and v_opcontent_dst = 0 then 
      P_DTMS_UPDATE_SAP(v_pkvalue,v_opcontent_ori,v_opcontent_dst,'invoice');--自治事务，调用这个过程的时候它就会独立于调用它的父事务进行操作 
      RAISE_APPLICATION_ERROR(-20100, 'Cannot Modify T_DTMS_TAX_INVOICE.EXPORT_TO_SAP From 1 To 0.');--抛出异常，RAISE_APPLICATION_ERROR(num,msg)，num在-20000到-20999之间，msg写你希望抛出的异常。 
    end if; 
  end case; 
end;